Robocopy - Wekelijks backup schema

Hieronder een script voor het maken van backups met een wekelijks roulatieschema. Voor elke dag van de week wordt een andere map gebruikt om de backup te maken.

Het scriptje maakt dus gebruikt van Robocopy en een klein programmaatje weekday.com (deze is te vinden in de downloads).

Let op: Door het gebruik van weekday.com is dit script niet bruikbaar op 64-bit systemen, dit kan wel met dit script.

In regel 13 kun je de brondirectory opgeven, in regel 14 de doeldirectory.

 

@echo off
cls
REM **********************************************************
REM Daily robocopy backup to a weekday folder
REM
REM This batchfile needs Robocopy and weekday.com
REM
REM Created by Cas
REM **********************************************************

REM declare variables
REM sourcedir en targetdir can be an UNC- or local path
set sourcedir=H:\bron_dir
set targetdir=Q:\doel_dir
set logfile=%targetdir%\robocopylog.txt
set day=

REM find day of week with an external programm called weekday.com
weekday.com
if errorlevel 0 if not errorlevel 1 set day=Sunday
if errorlevel 1 if not errorlevel 2 set day=Monday
if errorlevel 2 if not errorlevel 3 set day=Tuesday
if errorlevel 3 if not errorlevel 4 set day=Wednesday
if errorlevel 4 if not errorlevel 5 set day=Thursday
if errorlevel 5 if not errorlevel 6 set day=Friday
if errorlevel 6 set day=Saturday
echo %day%
if exist "%targetdir%\%day%" goto docopy
md "%targetdir%\%day%"

:docopy
robocopy "%sourcedir%" "%targetdir%\%day%" *.* /XO /COPY:DATSO /E /ZB /purge /R:10 /log:"%logfile%" /NP

:Done
set sourcedir=
set targetdir=
set logfile=
set day=